Skip to content
Snippets Groups Projects
Select Git revision
  • 672e196aa492cbd9013decc2d41d2e646e6f22f8
  • next default protected
  • next-test
  • classic-netcode-fixes
  • fix-dedi-pthread
  • fix-enemy-target
  • master protected
  • better-distance-math
  • movie
  • softcode-info
  • acs
  • clipmidtex
  • custom-map-names
  • nogravity-trampolines
  • 2214-pre4
  • 2214-pre3
  • just-in-case
  • fix-opengl-parameter-crash
  • 2214-pre2
  • 2214-pre1
  • delfile2
  • SRB2_release_2.2.15
  • SRB2_release_2.2.13
  • SRB2_release_2.2.12
  • SRB2_release_2.2.11
  • SRB2_release_2.2.10
  • SRB2_release_2.2.9
  • SRB2_release_2.2.8
  • SRB2_release_2.2.7
  • SRB2_release_2.2.6
  • SRB2_release_2.2.5
  • SRB2_release_2.2.4
  • SRB2_release_2.2.3
  • SRB2_release_2.2.2
  • SRB2_release_2.2.1
  • SRB2_release_2.2.0
  • SRB2_release_2.1.25
  • SRB2_release_2.1.24
  • SRB2_release_2.1.23
  • SRB2_release_2.1.22
  • SRB2_release_2.1.21
41 results

m_bbox.c

Blame
  • GitUtilities.cmake NaN GiB
    # Git utilities
    
    if(__GitUtilities)
    	return()
    endif()
    
    set(__GitUtilities ON)
    
    macro(_git_command)
    	execute_process(
    		COMMAND "${GIT_EXECUTABLE}" ${ARGN}
    		WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
    		OUTPUT_VARIABLE output
    		ERROR_QUIET
    		OUTPUT_STRIP_TRAILING_WHITESPACE
    	)
    endmacro()
    
    macro(_git_easy_command)
    	_git_command(${ARGN})
    	set(${variable} "${output}" PARENT_SCOPE)
    endmacro()
    
    function(git_current_branch variable)
    	_git_command(symbolic-ref -q --short HEAD)
    
    	# If a detached head, a ref could still be resolved.
    	if("${output}" STREQUAL "")
    		_git_command(describe --all --exact-match)
    
    		# Get the ref, in the form heads/master or
    		# remotes/origin/master so isolate the final part.
    		string(REGEX REPLACE ".*/" "" output "${output}")
    	endif()
    
    	set(${variable} "${output}" PARENT_SCOPE)
    endfunction()
    
    function(git_latest_commit variable)
    	_git_easy_command(rev-parse --short HEAD)
    endfunction()
    
    function(git_working_tree_dirty variable)
    	_git_command(status --porcelain -uno)
    
    	if(output STREQUAL "")
    		set(${variable} FALSE PARENT_SCOPE)
    	else()
    		set(${variable} TRUE PARENT_SCOPE)
    	endif()
    endfunction()
    
    function(git_subject variable)
    	_git_easy_command(log -1 --format=%s)
    endfunction()
    
    function(get_git_dir variable)
    	_git_easy_command(rev-parse --git-dir)
    endfunction()